blob: 12398652c9e6bb5a52e3e631ffc57713cf9d474f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Sven-Hendrik Haase <svenstaro@gmail.com>
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Thomas Baechler <thomas@archlinux.org>
pkgname=nvidia
pkgver=460.67
pkgrel=4
pkgdesc="NVIDIA drivers for linux"
arch=('x86_64')
url="https://www.nvidia.com/"
makedepends=('linux-headers' "nvidia-dkms=$pkgver")
provides=('NVIDIA-MODULE')
license=('custom')
options=('!strip')
build() {
_kernver=$(</usr/src/linux/version)
fakeroot dkms build --dkmstree "${srcdir}" -m nvidia/${pkgver} -k ${_kernver}
}
package() {
depends=('linux' "nvidia-utils=${pkgver}" 'libglvnd')
_kernver="$(</usr/src/linux/version)"
install -Dt "${pkgdir}/usr/lib/modules/${_kernver}/extramodules" -m644 \
nvidia/${pkgver}/${_kernver}/${CARCH}/module/*
# compress each module individually
find "$pkgdir" -name '*.ko' -exec xz -T1 {} +
echo "blacklist nouveau" |
install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modprobe.d/${pkgname}.conf"
install -Dt "${pkgdir}/usr/share/licenses/${pkgname}" -m644 \
/usr/share/licenses/nvidia-dkms/LICENSE
}
|